Die TommyGun IDE bietet die Möglichkeit recht einfach Sprites und Karten anzulegen und sie in ein Format für unterschiedliche 8-bit Computer zu konvertieren. Nachfolgend ist eine Spriteroutine zur Darstellung der Sprites aus TommyGun beschrieben, die von Prodatron optimiert wurde.

1

;*************************************
; SPRITE ROUTINE WITHOUT TRANSPARENCY
;
; DE = source address of the sprite
; (includes header with 1B width [64byte maximum!], 1B height)
; HL = destination address
;*************************************
writesprite:
ex de,hl
ld a,64
sub (hl)
add a
ld (width1+1),a
xor a
sub (hl)
ld (width2+1),a
inc hl
ld a,(hl)
inc hl
ex de,hl
width1: jr width1
ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi
ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi
ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi
ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi
ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi
ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi:ldi
ldi:ldi:ldi:ldi
width2: ld bc,#700
add hl,bc
jr nc,width3
ld bc,#c050
add hl,bc
width3: dec a
jp nz,width1
ret